Mage Macros

Offensive Macros

# Spammable Arcane Missiles
This macro prevents you from interrupting an Arcane Missiles cast by recasting too early.

/cast [nochanneling:Arcane Missiles] Arcane Missiles

# Interrupt Ice Lance
Mostly for Frostbite mages, this macro stops whatever spell you were casting and casts Ice Lance.

/stopcasting
/cast Ice Lance

# Opener Pyroblast
This macro casts Pyroblast when you’re pulling. If you’re out of combat, it casts Fireball.

/cast [nocombat] Pyroblast; Fireball

# Modifier Pyroblast
For those with 8/8 Netherwind or similar proc PoM effects, this will ordinarily cast Fireball, but will use Pyroblast instead if you hold Alt. Because of latency, you won’t be able to cast as fast as possible and make use of this. The same was true of old automatic NW macros anyway.

/cast [modifier:alt] Pyroblast; Fireball

# Frostbolt(Rank 1) Kiting
Hold alt for the fast casting snare, or cast your maximum rank.

/cast [modifier:alt] Frostbolt(rank 1); Frostbolt

# Stealth Breaker Arcane Explosion
On a normal key press or click, the first macro casts Arcane Explosion (maximum rank), but on a right click it uses Rank 1. The second option automatically downranks if you're out of combat.

/cast [button:2] Arcane Explosion(Rank 1); Arcane Explosion

/cast [nocombat] Arcane Explosion(Rank 1); Arcane Explosion

# One-Button Blizzard/Flamestrike
Click for Blizzard, or alt-click for Flamestrike.

/cast [modifier:alt] Flame Strike; Blizzard

# Castsequence Attack Routine
This is a cast sequence designed for mana efficiency - three Scorches and an Arcane Blast. It will reset to Arcane Blast if not pressed for 7 seconds (at least enough time for the debuff to begin to fade).

/castsequence reset=7 Arcane Blast, Scorch, Scorch, Scorch

# Friendly Fire Targeting
Replacing spells with this macro will cause you to cast them at your target’s target if you’re targeting a unit which cannot be attacked.

/cast [harm]Fireball; [target=targettarget]Fireball

# Cooldown Burners
Automatically casting spells or using trinkets whenever they are cooled down can still be done, if the spells don’t cause a global cooldown when activated. However, any time the trinket or spell is not ready, error text is displayed, error speech is triggered, and the “spell failed” sound effect is played. More complex scripts can remove the text, but I have not found a way to remove the failure sound. Regardless, here are two such macros.

/use Zandalarian Hero Charm
/stopcasting
/cast Fireball

/cast Combustion
/stopcasting
/cast Fireball

# I.W.I.N Buttons
These are a number of macros to instantly activate spell enhancers and cast your attack. First, the troll only berserking & haste trinket combo…

/use Mind Quickening Gem
/stopcasting
/cast Berserking
/stopcasting
/cast Fireball

…and the classic Presence of Mind, Arcane Power, and trinket macro.

/cast Presence of Mind
/stopcasting
/cast Arcane Power
/stopcasting
/use Vengeance of the Illidari
/stopcasting
/cast Pyroblast

# Pet Tricks: the Water Elemental and you.
Spammable Summon & Attack – This will summon your pet, and if pressed again, will set it to attack your target ones the lag on summoning finishes. Spamming is okay, and won’t cause your pet’s first waterbolt to cancel and restart.

/cast [nopet] Summon Water Elemental
/stopmacro [target=pettarget, exists]
/petattack

Summon & Freeze – Summons or activates the ranged frost nova power, Freeze. Using normal cast commands has been unreliable for this power.

/cast [nopet] Summon Water Elemental
/stopmacro [nopet]
/click PetActionButton5

Last edited by Faytx on Wed Feb 28, 2007 3:38 pm; edited 1 time in total

Defensive Macros

# Blink & Look
Stops any cast or channel and Blinks you forward instead. Then, if your target is an enemy, flips your camera angle 180 degrees. Macroes cannot turn your character, only the camera, so a two-button mouse move will be needed to face your attacker again.

/stopcasting
/cast Blink
/stopmacro [noharm]
/script FlipCameraYaw(180)

# Decurse
A reasonable replacement for the defunct decursive addon, hitting this button will remove a curse from whoever’s unit frame or 3D figure your cursor is hovering over. If your mouse is over a hostile or no target, you’ll decurse yourself.

/cast [target=mouseover, help] Remove Lesser Curse; [target=player] Remove Lesser Curse

# Interrupt Counterspell
Stops what you’re casting to immediately cast Counterspell.

/stopcasting
/cast Counterspell

# Your Favorite Harmless Animal, Polymorph
Polymorph: Focus – Sets your focus to your target and polymorphs it with a left click. Sheeps your focus without changing targets if you right click.

/cast [button:2, target=focus] Polymorph; Polymorph
/focus [nobutton:2]

Polymorph: Spam – Casts Detect Magic, sets the Star raid icon, sets your focus, and announces to your party or raid group your intention to sheep the <level> <gender> <race> target. How’s that for a chat spamming polymorph announcement?

/cast detect magic
/focus
/script SetRaidTarget("focus", 1)
/script if UnitSex("target")==1 then g="female " else g="male " end;s="I'm going to sheep a "..g..UnitLevel("target").." %T";c="Party";if GetNumRaidMembers()>0 then c="raid" end;SendChatMessage(s,c)

Polymorph: Random – This macro randomly chooses the harmless animal your enemy will some impersonate.

/castrandom Polymorph, Polymorph:Pig, Polymorph:Turtle

Polymorph: Dismount - Great for PvP, this will dismount you and begin a Polymorph cast immediately (as long as you stopped moving).

#showtooltip Polymorph
/dismount [mounted]
/cast Polymorph

Polymorph: Target Alert - This script will whisper any member of your party who is targetting your target. Click it before or while sheeping to help clear things up.

/script u=UnitIsUnit;c="Party";t="Target";for i=0,40 do if not u(c..i,"player") then if u(c..i..t,t) then n,r=UnitName(c..i) SendChatMessage("I am Polymorphing your target!","WHISPER",this.language,n) end end end

# Shapeshifting, Ice Cube Form
Breakable Ice Block – A 1.5 second “dead time” on toggle buttons like Ice Block was implemented to prevent unintentionally canceling buffs by spamming. This macro will restore previous functionality so Ice Block can be used to cancel debuffs almost instantaneously.

/cancelaura Ice Block
/cast Ice Block

Ice Block/Cold Snap – A macro allows rapid recasting of Ice Block by incorporating Cold Snap. The reset should be changed to 240 for Ice Floes.

/cancelAura Ice Block
/castSequence reset=300 Ice Block, Cold Snap

Break & Counterspell – This breaks Ice Block and immediately Counterspells your target.

/cancelaura Ice Block
/cast Counterspell

Break’n’Blink – This breaks Ice Block and immediately Blinks you forward.

/cancelaura Ice Block
/cast Blink

# One-Button Wards
Left click for Fire Ward, right click for Frost Ward

/cast [button:2] Frost Ward; Fire Ward

# Ice Barrier & Mana Shield
This cast sequence will use a single button to cast Ice Barrier, then Mana Shield. If only Ice Barrier is cast, it will reset to Ice Barrier again in 30 seconds (reset should be changed to 24 for Ice Floes). The problem is, this isn’t a real cooldown test, it’s just a counter from the previous button push. Casting Mana Shield will move the sequence back to Ice Barrier, even if it is not yet ready. Adding another Mana Shield to the sequence would stop the pseudo-cooldown timing, by not pushing to Ice Barrier until 30 seconds after the Last mana shield cast.

/castSequence reset=30 Ice Barrier, Mana Shield

# Self-Bandaging – Although this one doesn’t actually involve a mage spell, it is extremely useful. If your target can be healed, you bandage it, otherwise you bandage yourself (without losing your target).

/use [help]Heavy Netherweave Bandage; [target=player]Heavy Netherweave Bandage

Utility Macros

# Mana Gems
This macro sequentially conjures all your mana gems on right clicks, and uses the highest level one available on left click. As a fall-through macro, this will cause error messages when used to consume gems.

/castsequence [button:2] reset=120 Conjure Mana Emerald, Conjure Mana Ruby, Conjure Mana Citrine, Conjure Mana Jade, Conjure Mana Agate
/stopmacro [button:2]
/use Mana Emerald
/use Mana Ruby
/use Mana Citrine
/use Mana Jade
/use Mana Agate

# Evocation
First two clicks equip your spirit weapons, third click casts Evocation. Right clicking puts back on DPS weaponry.

/castsequence [button:1] reset=10 Serpentcrest Life-Staff, Marli's Touch, Evocation
/stopmacro [button:1]
/equip Time-Shifted Dagger
/equip The Saga of Terokk
/equip Nether-Core's Control Rod

# Food & Water – This macro has you eat and drink with a click, conjure water with shift-click, and conjure food with shift-right-click.

/use [nomodifier] Conjured Glacial Water
/use [nomodifier] Conjured Croissant
/cast [modifier:shift, button:2] Conjure Food;[modifier:shift] Conjure Water

# Smart Dampen/Amplify
Left clicks Dampen Magic, right clicks Amplify; if your target is in your party, it buffs him, otherwise it buffs you instead.

/cast [button:2, party] Amplify Magic; [button:2, target=player]Amplify Magic; [party] Dampen Magic; [target=player] Dampen Magic

# Self Buff Sequence
Insert your own favorite soloing buffs, and press one button three times to cast them.

/castsequence [target=player] reset=600 Dampen Magic, Arcane Intellect, Mage Armor

# One-Button Armor
Click for Mage Armor, right click for Molten Armor, alt-click for Ice Armor.

/cast [modifier:alt]Ice Armor; [button:2]Molten Armor; Mage Armor

# One-Button Portal
Useful for those below level 65 to get around and help their friends get around. Click to portal to Ironforge (Orgrimmar), alt for Stormwind (Undercity), control for Darnassus (Thunder Bluff), and shift for Exodar (Silvermoon).

/cast [modifier:shift] Portal: Exodar; [modifier:alt] Portal: Stormwind; [modifier:ctrl] Portal: Darnassus; Portal: Ironforge

/cast [modifier:shift] Portal: Silvermoon; [modifier:alt] Portal: Undercity; [modifier:ctrl] Portal: Thunder Bluff; Portal: Orgrimmar

# One-Button Teleport
Here’s the same thing as the Portal macro, but just for you. It’s not useful past level 59.

/cast [modifier:shift] Teleport: Exodar; [modifier:alt] Teleport: Stormwind; [modifier:ctrl] Teleport: Darnassus; Teleport: Ironforge

/cast [modifier:shift] Teleport: Silvermoon; [modifier:alt] Teleport: Undercity; [modifier:ctrl] Teleport: Thunder Bluff; Teleport: Orgrimmar

# High Level Portal & Teleport
Once you’re level 65, this will get you anywhere. Click for portal, right click for teleport. This one’s even the same for Horde and Alliance.

/cast [button:2] Teleport:Shattrath; Portal:Shattrath

thanks d00d